#include "colors.inc"

#declare axes_radius = .2
#declare axes_length = 4
#declare Axis = union {
	cone {
		<axes_length*1.2,0,0>,0,
		<axes_length*1,0,0>,axes_radius*2
	}
	cylinder {
		<-axes_length,0,0>,<axes_length,0,0>,axes_radius
	}
}
union {
	object { Axis }
	text {
		ttf "TIMROM.TTF",
		"+X",axes_radius,0
		translate <axes_length,axes_radius*1.5,0>
	}
	text {
		ttf "TIMROM.TTF",
		"-X",axes_radius,0
		translate <-axes_length,axes_radius*1.5,0>
	}
	pigment { color Red }
}

union {
	object { Axis rotate <0,-90,0> }
	text {
		ttf "TIMROM.TTF",
		"+Z",axes_radius,0
		translate <axes_radius*1.25,axes_radius*1.5,axes_length>
	}
	text {
		ttf "TIMROM.TTF",
		"-Z",axes_radius,0
		translate <-axes_radius*1.25-1,axes_radius*1.5,-axes_length>
	}
	pigment { color Green }
}

union {
	object { Axis rotate <0,0,90> }
	text {
		ttf "TIMROM.TTF",
		"+Y",axes_radius,0
		translate <axes_radius*1.25,axes_length,0>
	}
	text {
		ttf "TIMROM.TTF",
		"-Y",axes_radius,0
		translate <axes_radius*1.25,-axes_length,0>
	}
	pigment { color Blue }
}


camera {
	location <axes_length/1.2,axes_length/1.3,-axes_length*2>
	look_at <0,0,axes_length>
}

light_source {
	<axes_length,axes_length*3,-axes_length*2>, color White
}

background {
	color White
}