//We are going to be using colors, textures, distances, and metals
#include "colors.inc"
#include "textures.inc"
#include "distances.inc"
#include "metals.inc"

//create a bullet
union {
	difference {
		//the basic bullet shape
		lathe {
			linear_spline
			10,
			<0,2.1>*centimeters,
			<1.1/2,2.1>*centimeters,
			<1.1/2,.35>*centimeters,
			<.9/2,.2>*centimeters,
			<.9/2,.1>*centimeters,
			<1.1/2,.1>*centimeters,		
			<1.1/2,0>*centimeters,
			<.5/2,0>*centimeters,
			<.48/2,.2>*centimeters,
			<0,.2>*centimeters
		}
		
		//hollow it out
		cylinder {
			<0,.39,0>*centimeters,<0,2.5,0>*centimeters,
			1.08/2*centimeters
		}
	}
	
	//the dented silver primer button
	difference {
		//the silver button
		superellipsoid { <1,.1>
			rotate <90,0,0>
			scale <.05,.005,.05>
			translate <0,.024,0>*centimeters
			texture { T_Silver_3B }
		}
		//the dent
		sphere {
			<0,0,0>.059*centimeters
			scale <2,.5,1>
			translate <-.024,0,0>*centimeters
			texture { T_Silver_3A }
		}
	}

	texture {
		T_Brass_3A
	}
		
	translate <0,-1,0>*centimeters
	rotate <75,0,0>
}

//place the camera 4 centimeters back
camera {
	location <0,0,-4>*centimeters
	look_at <0,0,0>*centimeters
}

//place the light_source 1 foot high and 2 feet back
light_source {
	<0,1,-2>
	color White
}

//make the background white
background {
	color White
}