#include "colors.inc"

camera {
	location <0,0,-7.35>
	look_at <0,0,0>
}

light_source {
	<5,15,-50>
	color White
}

background { color White }


#declare Text_Color = texture {
	pigment {
		image_map {
			gif ":Images:John Harvard's Pub"
//			gif ":Images:The Pig"
			once
		}
		scale <4/3,1,1>
		scale 7.2
		translate <-.13,-2.16,0>
	}
}
#declare text_cut_texture = texture {
	pigment { color White }
	finish { ambient 1 }
}

#declare text_depth = .05;
#declare thick_font = "ArialBl.ttf"
#declare thin_font = "Arial.ttf"

union {
	text {
		ttf thick_font
		"small press expo"
		text_depth,0
		translate <0,2.15,0>
	}
	difference {
		text {
			ttf thick_font
			"SPX"
			text_depth,0
			scale <4.25,4.25,1>
		}
		text {
			ttf thin_font
			"98"
			text_depth,0
			scale <.822,.822,1>
			texture { text_cut_texture }
			translate <8.165,.01,-text_depth*.05>
		}
		translate <0,-1.25,0>
	}
	difference {
		box {
			<-.13,-.16,0>,
			<9.5,.59,text_depth>
		}
		text {
			ttf thin_font
			"September 25-27 Bethesda, MD"
			text_depth*1.1,0
			scale <.66,.66,1>
			texture { text_cut_texture }
			translate <0,0,-text_depth*.05>
		}
		translate <0,-2,0>
	}
	texture { Text_Color }
	translate <-4.7,0,0>
}